/*
  Simple test of Cam2 module with focusing.
*/
use cam2, graph as g, ui, audio

// take an image to "file"
function take(file)
  if cam2.focus(null)=0 then
    // focus not supported: directly take image
    audio.beep(880, 200);
    cam2.take(file)
  else
    // start focusing
    cam2.focus(true);
    // wait 2 seconds until focusing completes
    if cam2.focus(2000) then
      audio.beep(1760, 100);
      cam2.take(file)
    else
      audio.beep(440, 800)
    end
  end
end

// turn camera on and obtain image size
s=cam2.on();
// show the graphics screen and obtain its size
g.show();
gs=g.size();
// compute scale such that preview fits
for scale in [1, 0.5, 0.25, 0.125] do
  vs=[scale*s[0], scale*s[1]];
  dx=gs[0]-vs[0]; dy=gs[1]-vs[1];
  if dx>=0 and dy>=0 then
    break
  end
end;
// show centered, scaled preview
x=dx/2; y=dy/2;
vs=cam2.view(x, y, scale);
// enable the pointer
ui.ptr(ui.relative);
ui.keys(ui.strokes);
clicked=false;
nr=0;
while true do
  // wait for pointer event
  cmd=ui.cmd();
  if isarray(cmd) then
    if cmd[2]&1#0 then
      if not clicked then
        // if clicked into the view finder, take an image
        if cmd[0]>=x and cmd[0]<x+vs[0] and
          cmd[1]>=y and cmd[1]<y+vs[1] then
          nr++;
          take("Cam2Test-" + nr + ".jpg")
        end;
        clicked=true
      end
    else
      clicked=false
    end
  elsif cmd=ui.gokey then
    nr++;
    take("Cam2Test-" + nr + ".jpg")
  end
end;
g.hide();
cam2.off()